Option Compare Database
Option Explicit

Private Sub Form_Load()
    Dim strlist As String
    Dim strFolder As String
    Dim strFile As String
    Dim strMap As String
    Dim intPos As Integer

    'Change mouse pointer to Hourglass in case load time is slow.
    DoCmd.Hourglass True

    'Map Folder
    strFolder = "C:\Temp_C\Maps\"

    'Get first file in map folder.
    strFile = Dir(strFolder & "*.JPG")

    'If none found , go to exit label.
    If strFile = "" Then
        MsgBox "Maps missing."
        GoTo exit_PROC
    End If

    'Loop until no files found.
    Do While strFile <> ""
        'Use intpos to find last backslash
        intPos = InStrRev(strFile, "\")
        'Build string for list box; 2 columns:FilePath & File name
        strlist = strlist & strFolder & strFile & ";" _
                & Mid(strFile, intPos + 1, Len(strFile) - 4) & ";"

        'Get next file
        strFile = Dir()
    Loop

    'Trim last semicolon
    If Right(strlist, 1) = ";" Then
        strlist = Left(strlist, Len(strlist) - 1)
    End If

    'Assign list to Listbox
    Me.lstFiles.RowSourceType = "Value List"
    Me.lstFiles.RowSource = strlist

exit_PROC:
    DoCmd.Hourglass False

End Sub

Private Sub cmdGetMap_Click()
    Me.Image12.Picture = Me.lstFiles

End Sub